Profilbild aus Spieler UUID - Geht das?

* Questions, answers and templates about scripting
* Fragen, Antworten und Beispiele zum Scripting

Re: Profilbild aus Spieler UUID - Geht das?

Beitragvon Eryn Galen » Di 24. Feb 2015, 13:43

Translate to English translate to German Translate to French Translate to Italian Translate to Spanish Translate to Portuguese Translate to Czech Перевести на русский язык 翻译成中国

Naja, ich tippe darauf, dass das evtl. daher rühren kann, mit welchem Viewer und welcher Version das Profilbild eingestellt wurde. Vielleicht löschst du es einfach mal, loggst aus. Dann wieder einloggen und das Profilbild neu einstellen. Vielleicht hilft es ja und kein Gridadmin hat Arbeit damit ;)
Benutzeravatar
Eryn Galen
 
Beiträge: 972
Registriert: So 13. Jan 2013, 22:48

Re: Profilbild aus Spieler UUID - Geht das?

Beitragvon Gubbly » Di 24. Feb 2015, 19:40

Translate to English translate to German Translate to French Translate to Italian Translate to Spanish Translate to Portuguese Translate to Czech Перевести на русский язык 翻译成中国

Naja, da ist eindeutig ein fehler. Denn hier funktioniert es.
Da kann man das script auch einfach ändern...
Dann sollte es immer gehen... Wenn sich auf der Seite nicht auch ein Fehler verbirgt.

Code: Alles auswählen
string left(string src, string divider)
{
    integer index = llSubStringIndex( src, divider );
    if(~index)return llDeleteSubString( src, index, -1);
    return src;
}

string right(string src, string divider)
{
    integer index = llSubStringIndex( src, divider );
    if(~index)return llDeleteSubString( src, 0, index + llStringLength(divider) - 1);
    return src;
}

key     requestid   =   NULL_KEY;

default
{
    touch_start(integer num_detected)
    {
        string  AgentURL    =   "http://metropolis.hypergrid.org/metrotools/modules/show_member.php?tp=0&big=1&agent="+ (string)llDetectedKey(0);
        requestid   = llHTTPRequest(AgentURL ,[HTTP_METHOD, "POST"],"");
    }
   
    http_response(key request_id, integer status, list metadata, string body)
    {
        if(request_id == requestid)llSetTexture(left(right(body, "show_map.php?region="), "\">"), ALL_SIDES);
    }
}


Ich vermiete Regionen, bei Interesse schreib mich einfach an.
The Sweetest Thing
Benutzeravatar
Gubbly
 
Beiträge: 251
Registriert: Sa 20. Jul 2013, 00:51

Re: Profilbild aus Spieler UUID - Geht das?

Beitragvon Copper Tomsen » Mo 2. Jan 2017, 16:26

Translate to English translate to German Translate to French Translate to Italian Translate to Spanish Translate to Portuguese Translate to Czech Перевести на русский язык 翻译成中国

Gubbly hat geschrieben:Hier ein script das auf knopfdruck das bild anzeigt.

Code: Alles auswählen
string left(string src, string divider)
{
    integer index = llSubStringIndex( src, divider );
    if(~index)return llDeleteSubString( src, index, -1);
    return src;
}

string right(string src, string divider)
{
    integer index = llSubStringIndex( src, divider );
    if(~index)return llDeleteSubString( src, 0, index + llStringLength(divider) - 1);
    return src;
}

key     requestid   =   NULL_KEY;

default
{
    touch_start(integer num_detected)
    {
        string  AgentURL    =   "http://metropolis.hypergrid.org/metrotools/modules/show_member.php?agent=" + (string)llDetectedKey(0);
        requestid   = llHTTPRequest(AgentURL ,[HTTP_METHOD, "POST"],"");
    }
   
    http_response(key request_id, integer status, list metadata, string body)
    {
        if(request_id == requestid)llSetTexture(left(right(body, "show_map.php?region="), "\"></a>"), ALL_SIDES);
    }
}




Also ich hatte bisher immer string AgentURL = "http://metropolis.hypergrid.org/metrotools/modules/show_member.php?tp=0&big=1&agent="+ (string)llDetectedKey(0);

Das hatte auch bis vor ca. 3 Wochen gut funktionieret.
Nun hab ich die o.g. Zeile eingefügt, aber Profilbilder sind von Besuchern auf dem Display nicht mehr zu sehen.
Es wird, auch nach zurücksetzen, Versuch auf mono zu kmplimieren, etc, nicht mehr.
Es wird immer noch der Besucher von vor 3 Wochen angezeigt. Hat sich die Http für metro Profilbilder geändert?

Ist eschon ein schönes gadget :ugeek:
Benutzeravatar
Copper Tomsen
 
Beiträge: 51
Registriert: Di 10. Nov 2015, 20:28
Wohnort: Veytan Outpost @ Gateway to the Stars

Re: Profilbild aus Spieler UUID - Geht das?

Beitragvon Lena Vanilli » Mo 2. Jan 2017, 18:54

Translate to English translate to German Translate to French Translate to Italian Translate to Spanish Translate to Portuguese Translate to Czech Перевести на русский язык 翻译成中国

Ich wusste gar nicht, dass ihr das nutzt. :o Ich hab deswegen mal den Background etwas hübscher gemacht. ;)
Alles wird gut!
Benutzeravatar
Lena Vanilli
Administrator
 
Beiträge: 3127
Registriert: Mi 1. Apr 2009, 11:23
Wohnort: Konstanz

Re: Profilbild aus Spieler UUID - Geht das?

Beitragvon Gubbly » Mi 11. Jan 2017, 17:39

Translate to English translate to German Translate to French Translate to Italian Translate to Spanish Translate to Portuguese Translate to Czech Перевести на русский язык 翻译成中国

Das ganze war sowieso ein blöder Ansatz es von der Website zu holen. Ich empfehle deshalb dieses Script zu nutzen, da es auch über das HG funktioniert und nicht von irgendwelchen Webseiten abhängig ist wo sich irgendwann mal was ändern kann und dann nichts mehr funktioniert.

Tut das selbe wie das Script davor. Holt sich die UUID der Profil Textur und legt sie bei einem touch auf den Prim.

Code: Alles auswählen
key     m_http_request_key_profile_url  =   NULL_KEY;
key     m_http_request_key_image_uuid   =   NULL_KEY;

getProfileServer(string _homeURI, key _user)
    {
        string request = "<?xml version=\"1.0\" encoding=\"utf-8\"?><methodCall><methodName>get_server_urls</methodName><params><param><value><struct><member><name>userID</name><value><string>"+ _user +"</string></value></member></struct></value></param></params></methodCall>";
        m_http_request_key_profile_url = llHTTPRequest(_homeURI, [HTTP_METHOD, "POST", HTTP_MIMETYPE, "application/xml"], request);
    }

getProfileImage(string _profilServer, key _user)
    {
        string request = "{\"jsonrpc\":\"2.0\",\"id\":\"" + llGenerateKey() + "\",\"method\":\"avatar_properties_request\",\"params\":{\"UserId\":\"" + _user + "\"}}";
        m_http_request_key_image_uuid = llHTTPRequest(_profilServer, [HTTP_METHOD, "POST", HTTP_MIMETYPE, "application/json-rpc"], request);
    }
   
key m_lastUser  =   NULL_KEY;
   
default
{
    touch_start(integer i)
    {
        m_lastUser = llDetectedKey(0);
        getProfileServer(osGetAvatarHomeURI(m_lastUser), m_lastUser);
    }
   
    http_response(key request_id, integer status, list metadata, string body)
    {
        if (request_id == m_http_request_key_profile_url)
        {
            list _serverData = llParseString2List(body, ["><", ">", "<"], []);
            integer _ll = llGetListLength(_serverData);
           
            integer index;// default is 0
            while (index < _ll)
            {
                if(llList2String(_serverData, index) == "SRV_ProfileServerURI")
                {
                    getProfileImage(llList2String(_serverData, index + 4), m_lastUser);
                }
                index++;
            }
        }
       
        if (request_id == m_http_request_key_image_uuid)
        {
       
            list _serverData = llParseString2List(body, ["\":\"", "\",\""], []);
            integer _ll = llGetListLength(_serverData);
           
            integer index;// default is 0
            while (index < _ll)
            {
                if(llList2String(_serverData, index) == "ImageId")
                {
                    llSetTexture(llList2String(_serverData, index + 1), ALL_SIDES);
                }
                index++;
            }
        } 
    }
}
Ich vermiete Regionen, bei Interesse schreib mich einfach an.
The Sweetest Thing
Benutzeravatar
Gubbly
 
Beiträge: 251
Registriert: Sa 20. Jul 2013, 00:51

Vorherige

Zurück zu Scripting

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 0 Gäste



Powered by phpBB

Deutsche Übersetzung durch phpBB.de
.

Style designed by Artodia.